cmake_minimum_required(VERSION 3.8)
project(g2_2025_imu_reader_pkg)

if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  add_compile_options(-Wall -Wextra -Wpedantic)
endif()

# external packages
include(FetchContent)

FetchContent_Declare(
    tomlplusplus
    GIT_REPOSITORY https://github.com/marzer/tomlplusplus.git
    GIT_TAG v3.4.0
)

FetchContent_MakeAvailable(tomlplusplus)

FetchContent_Declare(
    nlohmann_json
    GIT_REPOSITORY https://github.com/nlohmann/json.git
    GIT_TAG v3.12.0
)

FetchContent_MakeAvailable(nlohmann_json)

# find dependencies
find_package(ament_cmake REQUIRED)
find_package(rclcpp REQUIRED)
find_package(rclcpp_action REQUIRED)
find_package(std_msgs REQUIRED)
find_package(sensor_msgs REQUIRED)
find_package(rclcpp_lifecycle REQUIRED)

add_executable(g2_2025_imu_database_writer_node
    src/g2_2025_imu_database_writer_node/Main.cpp
    src/database/DatabaseManager.cpp
    src/config/ConfigManager.cpp
    src/g2_2025_imu_database_writer_node/nodes/IMUDatabaseWriter.cpp
)

target_include_directories(g2_2025_imu_database_writer_node PRIVATE
    ${CMAKE_CURRENT_SOURCE_DIR}/src
    ${CMAKE_CURRENT_SOURCE_DIR}/src/g2_2025_imu_database_writer_node
)
ament_target_dependencies(g2_2025_imu_database_writer_node rclcpp sensor_msgs)
target_link_libraries(g2_2025_imu_database_writer_node pqxx pq tomlplusplus::tomlplusplus)

add_executable(g2_2025_lifecycle_node
    src/g2_2025_lifecycle_node/Main.cpp
    src/g2_2025_lifecycle_node/nodes/HardwareInterface.cpp
    src/g2_2025_lifecycle_node/nodes/LifecycleManager.cpp
    lib/serialib.cpp
)

target_include_directories(g2_2025_lifecycle_node PRIVATE
    ${CMAKE_CURRENT_SOURCE_DIR}/src
    ${CMAKE_CURRENT_SOURCE_DIR}/lib
    ${CMAKE_CURRENT_SOURCE_DIR}/src/g2_2025_lifecycle_node
)
ament_target_dependencies(g2_2025_lifecycle_node rclcpp rclcpp_lifecycle std_msgs sensor_msgs)

target_link_libraries(g2_2025_lifecycle_node
  paho-mqttpp3
  paho-mqtt3c
  nlohmann_json::nlohmann_json
)

install(
    TARGETS
        g2_2025_imu_database_writer_node
        g2_2025_lifecycle_node
    DESTINATION lib/${PROJECT_NAME}
)

install(
    DIRECTORY launch
    DESTINATION share/${PROJECT_NAME}/
)
set_target_properties(g2_2025_lifecycle_node PROPERTIES INSTALL_RPATH "/usr/local/lib")

if(BUILD_TESTING)
  find_package(ament_cmake_gtest REQUIRED)

  # Add gtest for ConfigManager
  ament_add_gtest(${PROJECT_NAME}_test_config_manager
    test/ConfigManager.test.cpp
    src/config/ConfigManager.cpp
  )
  target_include_directories(${PROJECT_NAME}_test_config_manager PRIVATE
    ${CMAKE_CURRENT_SOURCE_DIR}/src
  )
  ament_target_dependencies(${PROJECT_NAME}_test_config_manager
    rclcpp
  )
  target_link_libraries(${PROJECT_NAME}_test_config_manager
    tomlplusplus::tomlplusplus
  )

  # Add gtest for IMUDatabaseWriter node
  ament_add_gtest(${PROJECT_NAME}_test_imu_database_writer
    test/IMUDatabaseWriter.test.cpp
    src/g2_2025_imu_database_writer_node/nodes/IMUDatabaseWriter.cpp
    src/database/DatabaseManager.cpp
    src/config/ConfigManager.cpp
  )
  target_include_directories(${PROJECT_NAME}_test_imu_database_writer PRIVATE
    ${CMAKE_CURRENT_SOURCE_DIR}/src
    ${CMAKE_CURRENT_SOURCE_DIR}/src/g2_2025_imu_database_writer_node
  )
  ament_target_dependencies(${PROJECT_NAME}_test_imu_database_writer
    rclcpp
    sensor_msgs
  )
  target_link_libraries(${PROJECT_NAME}_test_imu_database_writer
    pqxx pq tomlplusplus::tomlplusplus
  )

  # Add gtest for DatabaseManager
  ament_add_gtest(${PROJECT_NAME}_test_database_manager
    test/DatabaseManager.test.cpp
    src/database/DatabaseManager.cpp
    src/config/ConfigManager.cpp
  )
  target_include_directories(${PROJECT_NAME}_test_database_manager PRIVATE
    ${CMAKE_CURRENT_SOURCE_DIR}/src
  )
  ament_target_dependencies(${PROJECT_NAME}_test_database_manager
    rclcpp
  )
  target_link_libraries(${PROJECT_NAME}_test_database_manager
    pqxx pq tomlplusplus::tomlplusplus
  )

  ament_add_gtest(${PROJECT_NAME}_test_lifecycle_manager
    test/LifecycleManager.test.cpp
    src/g2_2025_lifecycle_node/nodes/LifecycleManager.cpp
    src/g2_2025_lifecycle_node/nodes/HardwareInterface.cpp
    lib/serialib.cpp
  )
  target_include_directories(${PROJECT_NAME}_test_lifecycle_manager PRIVATE
    ${CMAKE_CURRENT_SOURCE_DIR}/src
    ${CMAKE_CURRENT_SOURCE_DIR}/src/g2_2025_lifecycle_node
    ${CMAKE_CURRENT_SOURCE_DIR}/lib
  )
  ament_target_dependencies(${PROJECT_NAME}_test_lifecycle_manager
    rclcpp
    rclcpp_lifecycle
    std_msgs
    sensor_msgs
  )
  target_link_libraries(${PROJECT_NAME}_test_lifecycle_manager
    paho-mqttpp3
    paho-mqtt3c
    nlohmann_json::nlohmann_json
  )
  set_target_properties(${PROJECT_NAME}_test_lifecycle_manager PROPERTIES INSTALL_RPATH "/usr/local/lib")

  # Add Python integration tests
  #   find_package(ament_cmake_pytest REQUIRED)
  #   ament_add_pytest_test(${PROJECT_NAME}_integration_test test/test_integration_system.py
  #     TIMEOUT 60
  #   )
endif()

ament_package()
